Sports Illustrated for Kids - Awesome Athletes!/Sports Illustrated for Kids - Awesome Athletes!.iso/sd.dir/00005_Main FS.ls

Text File | 1996-04-18 | 3.8 KB | 154 lines

global gSDHelpUp, gSDNoPickUp, gSISystem, gSIActiveWindow, gSIHParentWnd

on mouseDown
  if gSISystem = "WIN" then
    set vHWnd to gSIActiveWindow(mCall)
    if vHWnd <> gSIHParentWnd then
      go(the frame)
      exit
    end if
  end if
  if gSDNoPickUp then
    set gSDNoPickUp to 0
    exit
  end if
  if gSDHelpUp then
    HSStatePut("sd2", "not1stTime", "1")
    set the visible of sprite 38 to 0
    set gSDHelpUp to 0
  end if
  set vPoint to point(the mouseH, the mouseV)
  set vBinLoc to BinLocation(vPoint)
  if vBinLoc <> 0 then
    ClickInBin(vBinLoc)
  else
    set vGridLoc to PuzzleLocation(vPoint)
    if vGridLoc <> EMPTY then
      ClickInPuzzle(vGridLoc)
    else
      beep()
    end if
  end if
end

on exitFrame
  global gSDDragging, cSDDragSprite
  if gSISystem = "WIN" then
    set vHWnd to gSIActiveWindow(mCall)
    if vHWnd <> gSIHParentWnd then
      go(the frame)
      exit
    end if
  end if
  if gSDDragging then
    set the locH of sprite cSDDragSprite to the mouseH
    set the locV of sprite cSDDragSprite to the mouseV
    updateStage()
  else
    UIRollover(44, 45)
  end if
  go(the frame)
end

on ClickInPuzzle aLoc
  global gSDDragging, gSDDragNum, gSDDragPiece, cSDDragSprite
  set vNew to GetPuzzleAt(aLoc)
  if gSDDragging then
    if not PieceFits(aLoc, gSDDragPiece) then
      puppetSound("boing")
      return
    end if
    set vRect to GetPuzzleRect(aLoc)
    set the castNum of sprite gSDDragNum to cast ("N_" & gSDDragPiece)
    set the locH of sprite gSDDragNum to getAt(vRect, 1) + (the width of cast ("N_" & gSDDragPiece) / 2)
    set the locV of sprite gSDDragNum to getAt(vRect, 2) + (the height of cast ("N_" & gSDDragPiece) / 2)
    PutPuzzleAt(aLoc, gSDDragPiece)
    EndDrag()
    CheckPuzzle()
  else
    PutPuzzleAt(aLoc, EMPTY)
  end if
  if vNew <> EMPTY then
    BeginDrag(vNew)
  end if
end

on ClickInBin aLoc
  global gSDDragging, gSDDragNum, gSDDragPiece
  set vNew to GetBinAt(aLoc)
  if gSDDragging then
    set vRect to GetBinRect(aLoc)
    set the castNum of sprite gSDDragNum to cast ("S_" & gSDDragPiece)
    set the locH of sprite gSDDragNum to getAt(vRect, 1) + (the width of cast ("S_" & gSDDragPiece) / 2)
    set the locV of sprite gSDDragNum to getAt(vRect, 2) + (the height of cast ("S_" & gSDDragPiece) / 2)
    PutBinAt(aLoc, gSDDragPiece)
    EndDrag()
    CheckPuzzle()
  else
    PutBinAt(aLoc, EMPTY)
  end if
  if vNew <> EMPTY then
    BeginDrag(vNew)
  end if
end

on BeginDrag aPiece
  global gSDDragging, cSDDragSprite, gSDDragNum, gSDDragPiece, cSDSpriteBase
  puppetSound("pickup")
  set gSDDragging to 1
  set gSDDragPiece to aPiece
  set the castNum of sprite cSDDragSprite to cast ("N_" & aPiece)
  set gSDDragNum to NameToNum(aPiece)
  set the locH of sprite cSDDragSprite to the mouseH
  set the locV of sprite cSDDragSprite to the mouseV
  set the visible of sprite gSDDragNum to 0
  set the visible of sprite cSDDragSprite to 1
  updateStage()
end

on EndDrag
  global gSDDragging, cSDDragSprite, gSDDragNum, gSDDragPiece
  puppetSound("putdown")
  set gSDDragging to 0
  set the visible of sprite cSDDragSprite to 0
  set the visible of sprite gSDDragNum to 1
  updateStage()
end

on PieceFits aLoc, aPiece
  if PieceType(aLoc) = PieceType(aPiece) then
    return 1
  else
    return 0
  end if
end

on PieceType aPiece
  set vVOdd to value(char 1 of aPiece) mod 2
  set vHOdd to value(char 3 of aPiece) mod 2
  if vHOdd then
    if vVOdd then
      return #vert
    else
      return #horiz
    end if
  else
    if vVOdd then
      return #horiz
    else
      return #vert
    end if
  end if
end

on CheckPuzzle
  global cSDSpriteBase
  if PuzzleComplete() then
    SetCursor(#wait)
    go("Install")
    repeat with vI = cSDSpriteBase + 1 to cSDSpriteBase + 36
      set the visible of sprite vI to 0
    end repeat
  end if
end